10 PRINT TAB(33);"LUNAR"
20 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
25 PRINT
26 PRINT
27 PRINT
30 PRINT "THIS IS A COMPUTER SIMULATION OF AN APOLLO LUNAR"
40 PRINT "LANDING CAPSULE."
41 PRINT
42 PRINT
50 PRINT "THE ON-BOARD COMPUTER HAS FAILED (IT WAS MADE BY"
60 PRINT "XEROX) SO YOU HAVE TO LAND THE CAPSULE MANUALLY."
70 PRINT
72 PRINT "SET BURN RATE OF RETRO ROCKETS TO ANY VALUE BETWEEN"
80 PRINT "0 (FREE FALL) AND 200 (MAXIMUM BURN) POUNDS PER SECOND."
90 PRINT "SET NEW BURN RATE EVERY 10 SECONDS."
100 PRINT "CAPSULE WEIGHT 32,500 LBS; FUEL WEIGHT 16,500 LBS."
110 PRINT
111 PRINT
112 PRINT
113 PRINT "GOOD LUCK"
120 L = 0
130 PRINT
131 PRINT " SEC", " MILES + FEET", " MPH", " LB FUEL", "BURN RATE"
132 PRINT
140 A = 120
141 V =1
142 M=33000
143 N=16500
144 G = 1E-3
145 Z = 1.8
146 W = 0
150 PRINT L, INT(A);INT(5280*(A-INT(A))),3600*V,M-N,
151 INPUT K
152 T =10
160 IF M-N<.001 THEN 240
170 IF T <.001 THEN 150
180 S = T
181 IF M>=N+S*K THEN 200
190 S = (M-N)/K
200 GOSUB 420
201 IF I <=0 THEN 340
210 IF V<=0 THEN 230
220 IF J<0 THEN 370
230 GOSUB 330
231 GOTO 160
240 PRINT "FUEL OUT AT";L;"SECONDS"
241 S = (-V+SQR(V*V+2*A*G))/G
250 V = V+G*S
251 L = L + S
260 W = 3600*V
261 PRINT "ON MOON AT";L;" SECONDS - IMPACT VELOCITY ";W;" MPH"
270 IF W <= 1.2 GOTO 432
272 PRINT
273 PRINT
274 PRINT
280 IF W <= 10 THEN 435
300 PRINT "SORRY THERE WERE NO SURVIVORS. YOU BLEW IT!"
310 PRINT "IN FACT, YOU BLASTED A NEW LUNAR CRATER";W*.277;" FEET DEEP"
320 GOTO 440
330 L = L + S
331 T = T -S
332 M = M -S*K
333 A = I
334 V = J
335 RETURN
340 IF S <5E-1 THEN 260
350 W = V +SQR(V*V+2*A*(G-Z*K/M))
351 S = 2 * A/W
360 GOSUB 420
361 GOSUB 330
362 GOTO 340
370 W= (1-M*G/(Z*K))/2
371 S = M*V/(Z*K*(W+SQR(W*W+V/Z)))+.05
372 GOSUB 420
380 IF I <= 0 THEN 340
390 GOSUB 330
391 IF J>0 THEN 160
400 IF V>0 THEN 370
410 GOTO 160
420 Q = S*K/M
421 J = V+G*S+Z*(-Q-Q*Q/2-Q^3/3-Q^4/4-Q^5/5)
430 I = A-G*S*S/2-V*S+Z*S*(Q/2+Q^2/6+Q^3/12+Q^4/20+Q^5/30)
431 RETURN
432 PRINT "PERFECT LANDING!"
433 GOTO 440
435 PRINT "CRAFT DAMAGE.  YOU'RE STRANDED UNTIL RESCUED"
440 PRINT
441 PRINT
442 PRINT
443 PRINT "TRY AGAIN??"
444 GOTO 70
450 END